哪位仁兄帮帮忙，把遗漏部分的翻译补上，这样小弟也好把所有的Lingo整理出来。
前段时间5D事情太多，Lingo没有整理，在这里，小弟先行道歉了。rotation

Syntax

the rotation of member whichQuickTimeMember
member(whichQuickTimeMember).rotation
sprite(whichSprite).rotation
the rotation of sprite whichSprite
Description

Cast member property and sprite property; controls the rotation of a QuickTime movie, animated GIF, Flash movie, or bitmap sprite within the sprite's bounding rectangle, without rotating that rectangle or the sprite's controller (in the case of QuickTime). In effect, the sprite's bounding rectangle acts as a window through which you can see the Flash or QuickTime movie. The bounding rectangles of bitmaps and animated GIFs change to accommodate the rotating image.

Score rotation works for a Flash movie only if obeyScoreRotation is set to TRUE.

A Flash movie rotates around its origin point as specified by its originMode property. A QuickTime movie rotates around the center of the bounding rectangle of the sprite. A bitmap rotates around the registration point of the image.

For QuickTime media, if the sprite's crop property is set to TRUE, rotating the sprite frequently moves part of the image out of the viewable area; when the sprite's crop property is set to FALSE, the image is scaled to fit within the bounding rectangle (which may cause image distortion).

You specify the rotation in degrees as a floating-point number.

The Score can retain information for rotating an image from +21,474,836.47° to -21,474,836.48° , allowing 59,652 full rotations in either direction.

When the rotation limit is reached (slightly past the 59,652th rotation), the rotation resets to +116.47° or -116.48° —not 0.00° . This is because +21,474,836.47° is equal to +116.47° , and -21,474,836.48° is equal to -116.48° (or +243.12° ). To avoid this reset condition, when you use Lingo to perform continuous rotation, constrain the angles to ±360° .

This property can be tested and set. The default value is 0.

Example

The following behavior causes a sprite to rotate continuously by 2° every time the playback head advances, limiting the angle to 360° :

property spriteNum

on prepareFrame me
    sprite(spriteNum).rotation = integer(sprite(spriteNum).rotation + 2) mod 360
end
Example

This frame script keeps the playback head looping in the current frame while it rotates a QuickTime sprite in channel 5 a full 360° in 16° increments. When the sprite has been rotated 360° , the playback head continues to the next frame.

on exitFrame
    if sprite(5).rotation < 360 then
        sprite(5).rotation = sprite(5).rotation + 16
        go the frame
    end if
end
Example

This handler accepts a sprite reference as a parameter and rotates a Flash movie sprite 360° in 10° increments:

on rotateMovie whichSprite
    repeat with i = 1 to 36
        sprite(whichSprite).rotation = i * 10
        updatestage
    end repeat
end
See also

flipH, flipV, obeyScoreRotation, originMode

pause()

Syntax

sound(channelNum).pause()
pause(sound(channelNum))
Description

This command suspends playback of the current sound in sound channel channelNum. A subsequent play() command will resume playback.

Example

This statement pauses playback of the sound cast member playing in sound channel 1.

sound(1).pause()
See also

breakLoop(), isBusy(), play() (sound), playNext(), queue(), rewind(), status, stop() (sound

period

Syntax

timeoutObject.period
Description

Object property; the number of milliseconds between timeout events sent by the timeOutObject to the timeout handler.

This property can be tested and set.

Example

This timeout handler decreases the timeout's period by one second each time it's invoked, until a minimum period of 2 seconds (2000 milliseconds) is reached:

on handleTimeout timeoutObject
    if timeoutObject.period > 2000 then
        timeoutObject.period = timeoutObject.period - 1000
    end if
end handleTimeout
See also

name (timeout property), persistent, target, time (timeout object property), timeout(), timeoutHandler, timeoutList

member (keyword)

Syntax

member whichCastMember
member whichCastMember of castLib whichCast
member(whichCastMember, whichCastLib)
Description

Keyword; indicates that the object specified by whichCastMember is a cast member. If whichCastMember is a string, it is used as the cast member name. If whichCastMember is an integer, it is used as the cast member number.

When playing back a movie as an applet, refer to cast members by number rather than by name to improve the applet's performance.

The member keyword is a specific reference to both a castLib and a member within it if used alone:

put sprite(12).member
-- (member 3 of castLib 2)
This property differs from the memberNum property of a sprite, which is always an integer designating position in a castLib but does not specify the castLib:

put sprite(12).memberNum
-- 3
The number of a member is also an absolute reference to a particular member in a particular castLib:

put sprite(12).member.number
-- 131075
Example

The following statement sets the hilite property of the button cast member named Enter Bid to TRUE:

member("Enter Bid").hilite = TRUE
Example

This statement puts the name of sound cast member 132 into the variable soundName:

soundName = member(132, "Viva Las Vegas").name
Example

This statement checks the type of member Jefferson Portrait in the castLib Presidents:

memberType = member("Jefferson Portrait", "Presidents").type
Example

This statement determines whether cast member 9 has a name assigned:

if member(9).name = EMPTY then exit
Example

You can check for the existence of a member by testing for its number:

memberCheck = member("Epiphany").number
if memberCheck = -1 then alert "Sorry, that member doesn't exist"
Example

Alternatively, you can check for the existence of a member by testing for its type:

memberCheck = member("Epiphany").type
if memberCheck = #empty then alert "Sorry, that member doesn't exist"
See also

memberNum

media

Syntax

member(whichCastMember).media
the media of member whichCastMember
Description

Cast member property; identifies the specified cast member as a set of numbers. Because setting the media member property can use large amounts of memory, this property is best used during authoring only.

You can use the media member property to copy the content of one cast member into another cast member by setting the second cast member's media value to the media value for the first cast member.

For a film loop cast member, the media member property specifies a selection of frames and channels in the Score.

To swap media in a projector, it's more efficient to set the member sprite property.

Example

This statement copies the content of the cast member Sunrise into the cast member Dawn by setting the media member property value for Dawn to the media member property value for Sunrise:

member("Dawn").media = member("Sunrise").media
See also

type (cast member property)

mci

Syntax

mci "string"
Description

Command; for Windows only, passes the strings specified by string to the Windows Media Control Interface (MCI) for control of multimedia extensions.

Note: Microsoft no longer recommends using the 16-bit MCI interface. Consider using third-party Xtras for this functionality instead.

Example

This statement makes the command play cdaudio from 200 to 600 track 7 play only when the movie plays back in Windows:

mci "play cdaudio from 200 to 600 track 7"

max()

Syntax

list.max()
max(list)
max(value1, value2, value3, ...)
Description

Function; returns the highest value in the specified list or the highest of a given series of values.

The max function also works with ASCII characters, similar to the way < and > operators work with strings.

Example

This handler assigns the variable Winner the maximum value in the list Bids, which consists of [#Castle:600, #Schmitz:750, #Wang:230]. The result is then inserted into the content of the field cast member Congratulations.

on findWinner Bids
    Winner = Bids.max()
    member("Congratulations").text = \
    "You have won, with a bid of $" & Winner &"!"
end

markerList

Syntax

the markerList
Description

Global property; contains a Lingo property list of the markers in the Score. The list is of the format:

frameNumber: "markerName"
This property can be tested but not set.

Example

This statement displays the list of markers in the Message window:

put the markerlist
-- [1: "Opening Credits", 15: "Main Menu", 26: "Closing Credits"]
marker()

See also

frameLabel, label(), marker(), labelList